CftClub.ru
Клуб специалистов ЦФТ-Банк

Копирование Pdf файла

 
Ответить на тему    Клуб специалистов ЦФТ-Банк (IBSO) -> Разработка в PL/PLUS. Оптимизация запросов Oracle
Предыдущая тема :: Следующая тема  
Автор Сообщение
Saftar
Участник


Вступление в Клуб: 18.01.2017
СообщениеСр Янв 18, 2017 15:31   Копирование Pdf файла Ответить с цитатой
Полезность: Нет оценки
Хочу скопировать PDF файл с одной локальной директории в другую как это можно сделать в PL PLUS. Например с диска C:\ на диск D:\
vtar
Эксперт


Вступление в Клуб: 20.03.2009
СообщениеСр Янв 18, 2017 17:25    Ответить с цитатой
Полезность: Нет оценки
в клиент-скрипте можно .

Справочник
MON. Прикреплённые файлы
MON_ATTACH

Операция
Прикрепить файл
NEW#AUTO

какой нибудь Call fso.CopyFile(file_source, dest_folder & dest_file)
Матвеев Евгений
Профи


Вступление в Клуб: 31.01.2012
СообщениеЧт Янв 19, 2017 12:30   Re: Копирование Pdf файла Ответить с цитатой
Полезность: Нет оценки
Saftar пишет:
Хочу скопировать PDF файл с одной локальной директории в другую как это можно сделать в PL PLUS. Например с диска C:\ на диск D:\


Согласен с Vtar, рабочее решение...
Подкину еще... более подробный пример [NEW_AUTO_REM]
Вся цепочка, включая изменение имени:

Код:

'Dim fso
' Процедура для создания папки назначения.
' Процедура создаёт все несуществующие папки, указанные в строке адреса
private Sub Create_Folder_Tree(fso, dest_folder)
   if dest_folder = "" then
      exit sub
   end if
   
   If not(fso.FolderExists(dest_folder)) Then
      Call Create_Folder_Tree(fso, fso.GetParentFolderName(dest_folder))
      fso.CreateFolder(dest_folder)
   End If
End Sub
 
' Процедура для копирования файла.
' Папка назначения может не существовать - процедура создаст её
' Параметры:
'    fso  объект для работы с файловой системой. Создаь этьот объект можно следующим оператором Set fso = CreateObject("Scripting.FileSystemObject")
'    file_source - Полное имя копируемого файла
'    dest_folder - Полный путь до папки, в которую необходимо скопировать файл
'    dest_file   - Новое имя файла.
private Sub copy_file(fso, file_source, dest_folder, dest_file)
   Call Create_Folder_Tree(fso, dest_folder)
   Call fso.CopyFile(file_source, dest_folder & dest_file)           
End Sub

Public Function Main(LastControl)

   If LastControl Is Nothing or LastControl Is Form1 Then
      ' Действия при загрузке формы

      Main = True 'Результат валидатора (True, False, NULL)   
      
   ElseIf LastControl Is OK Then
      On Error Resume Next
      Set fso = CreateObject("Scripting.FileSystemObject")
      If srcFileName.Text = "" or srcFolder.Text = "" then
         Call msgbox("Не выбран файл!", vbOKOnly+vbCritical, "Ошибка")
         Main = NULL
      ElseIf not(fso.FileExists(srcFolder.Text + srcFileName.Text )) then
         Call msgbox("Указанный файл не найден!", vbOKOnly+vbCritical, "Ошибка")
         Main = NULL
      Else
         if V_STORAGE.Value = "1" then
            'Выделение [расширения] из имени файла
            iPos = InStr(1,srcFileName.Text,".")
            iPosExt = iPos
            While iPos > 0
               iPosExt = iPos
               iPos = InStr(iPos+1, srcFileName.Text,".")
            Wend
            ' Добавление к имени файла id записи в БД
            if iPosExt > 0 Then
               dstFileName.Text = Left(srcFileName.Text, iPosExt-1) + "_" + id.Text + Mid(srcFileName.Text, iPosExt, 20)
            else
               dstFileName.Text = srcFileName.Text+ "_" + id.Text
            end if
            
            ' Копирование файла в хранилище
            Call copy_file(fso, srcFolder.Text + srcFileName.Text, dstFolder, dstFileName)
            
            If Err.number = 0 then
               Set fso = nothing
               Main = True
            'Если ошибка
            Else
               MsgBox "У вас не хватает прав на выполнение данной операции, обратитесь к Администратору", vbCritical, "Ошибка"
               Set fso = nothing
               Main = NULL
            End if
         else
            dstFolder = srcFolder.Text + srcFileName.Text   
            Main = True         
         end if
      End if
   ELSE
      Main = True
   
   End If

End Function

Saftar
Участник


Вступление в Клуб: 18.01.2017
СообщениеЧт Янв 19, 2017 14:01    Ответить с цитатой
Полезность: Нет оценки
Спасибо все работает)
Показать сообщения:   
Ответить на тему    Клуб специалистов ЦФТ-Банк (IBSO) -> Разработка в PL/PLUS. Оптимизация запросов Oracle Часовой пояс: GMT + 3
Страница 1 из 1

 
Перейти:  
Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете голосовать в опросах
Рейтинг@Mail.ru